Go to the first, previous, next, last section, table of contents.

Format Specification Syntax

docspec         : parseformat | format
                ;
parseformat     : record layout
                ;
format          : record layout speclist
                ;
record          : `record-sep:' REGEXP 
                ;
layout          :
                | `layout:' layoutspecs `end:' 
                ;
layoutspecs     : layoutspec
                | layoutspec layoutspecs
                ;
layoutspec      : `date:' REGEXP REGEXP date date date regexp
                | `headline:' REGEXP REGEXP INT regexp
                ;
speclist        : spec
                | spec speclist
                ;
spec            : `region:' REGEXP regexp
                  fieldlist
                  options
                  indexspecs
                  `end:' REGEXP
                ;
options         : 
                | option options
                ;
option          : `numeric:' regexp INT
                | `date:' date date date
                | `stemming'
                ;
regexp          : 
                | REGEXP 
                ;
indexspecs      : 
                | indexspec indexspecs
                ;
indexspec       : indextype dicts
                ;
indextype       : `TEXT'
                | `SOUNDEX'
                | `PHONIX'
                ;
dicts           : `GLOBAL' 
                | `LOCAL'  
                | `BOTH'   
                ;
date            : `day'    
                | `month' monthspec
                | `year'   
                ;
monthspec       :
                | `string' 
                ;                 
fieldlist       : 
                | WORD descr fieldlist
                ;
descr           : 
                | `"' any string `"' 
                ;


Go to the first, previous, next, last section, table of contents.